Repository for game things, mostly WoW
These are the relevant macros I use for my Beast Master Hunter. Some of these macros I created myself, most of them I modified from other peoples’ on various WoW-related forums. If you want to see how a macro would work, try them out. Some macros are not BM specific and are usable on any class. Some combine different things between specs on hunters so I don’t run out of “Muerr specific macro” space in the game macro panel UI. There is no specific order here. Hopefully this is helpful to someone.
Cast Binding Shot where your Cursor is pointed, rather than using the reticle.
#showtooltip
/cast [@cursor] Binding Shot
END
My call pet macro. This will summon the specified pet number if the pet is not dead or cast Revive Pet if the pet is dead. If a modifier is held, it will dismiss the pet. Otherwise, it will cast Mend Pet. It will cast Wake Up to ensure the pet is not feigning death.
Pet 1 is my Fel Core Hound (Ferocity), Pet 2 is my Spirit Beast (Tenacity). Pet 3 is a Silithid (Cunning).
#showtooltip
/use [@pet,nodead,nopet] Call Pet 1; [@pet,dead][nopet]Revive Pet;[mod]Dismiss Pet;Mend Pet
/cast Wake Up
/script UIErrorsFrame:Clear()
Cast spec-specific buffs with one button. Hold down a modifier (I use alt) to cast your aspect if BM or SV, otherwise the main cooldown will be used (nomod).
#showtooltip
/cast [spec:1, mod] Aspect of the Wild; [spec:3, mod] Aspect of the Eagle
/cast [spec:1, nomod] Bestial Wrath; [spec:2, nomod] Trueshot; [spec:3, nomod] Coordinated Assault
Interrupt! This can be used on mouseover if the current target isn’t casting. Works for all three specs.
#showtooltip [spec:1][spec:2] Counter Shot; [spec:3]Muzzle
/stopcasting
/stopcasting
/cast [@mouseover,exists, harm][] Counter Shot
/cast [@mouseover,exists, harm][] Muzzle
This puts the “core” ability for all three hunter specs on one button to save space in your macro UI.
#showtooltip
/petassist
/petattack
/use [spec:1][spec:3]Kill Command
/use [spec:2,@mouseover,harm,exists][spec:2]Aimed Shot
/use [pet]Claw(Basic Attack)
/use [pet]Bite(Basic Attack)
/use [pet]Smack(Basic Attack)
Similar to “core” above, this is for your “filler” and works for all three hunter specs.
#showtooltip
/use [spec:1,@mouseover,harm,exists][spec:1]Cobra Shot
/use [spec:2,@mouseover,harm,exists][spec:2]Arcane Shot
/use [spec:3]Raptor Strike
For BM and MM, focus generator macro.
#showtooltip
/use [spec:1,@mouseover,harm,exists][spec:1]Barbed Shot
/use [spec:2,@mouseover,harm,exists][spec:2]Steady Shot
/use [pet]Claw(Basic Attack)
/use [pet]Bite(Basic Attack)
/use [pet]Smack(Basic Attack)
Use these to snipe orbs on Explosive affix for M+, and win the admiration of your party.
/cast [@mouseover, exists, harm][] Cobra Shot
/cast [@mouseover, exists, harm][] Dire Beast
/cast [@mouseover, exists, harm][] Barbed Shot
OH SHIT FEIGN DEATH. Both you and your pet.
#showtooltip
/cast Feign Death
/cast Play Dead
If you’re using a Spirit Beast, you get Spirit Mend. You probably want to cast this on yourself, or maybe a mouse-over target.
#showtooltip
/use [@mouseover, help][help][@player] Spirit Mend
Usable on all hunter specs
Go to the Darkmoon Faire. Buy a Seafarer’s Slidewhistle with the fish currency. Then use this macro for your disengage. Hilarity ensues in raids “What the fuck is that whistling?”
#showtooltip
/use [nomod] Disengage
/use [mod] Aspect of the Cheetah
/use Seafarer's Slidewhistle
As an added bonus, I baked Cheetah in this if you hit a modifier.
As an added bonus, use this with Vengeful Retreat on your Demon Hunter, Blink/Shimmer on your Mage, etc, etc.
Set the tank as your focus. Or the healer, or whoever you want to troll… ;)
#showtooltip Misdirection
/stopcasting
/cast [help][@focus, help][@targettarget,help][@pet,exists] Misdirection
If talented, this handles casting Dire Beast (with mod:alt) or Murder of Crows (nomod).
#showtooltip
/targetenemy [dead][noexists]
/use [spec:1,talent:4/3,mod:alt,@mouseover, harm, exists][spec:1,talent:4/3,nomod]A Murder of Crows
/use [spec:1,talent:1/3,nomod,@mouseover, harm, exists][spec:1,talent:1/3,mod:alt]Dire Beast
/cast Auto Shot
Both SV and BM have activated abilities for their level 30 talent, so put those on one macro. Bonus: Chimaera Shot is a @mouseover, so you can use this on Explosive Orb weeks - and cleave to another mob nearby!
#showtooltip
/use [@mouseover,harm,spec:1,talent:2/3][spec:1,talent:2/3]Chimaera Shot
/use [spec:2, talent:2/3]Explosive Shot
/cast Auto Shot
Toss a freezing trap at your cursor without a modifier key, otherwise target the ground and place one. Strategically. You wish you had this macro when doing Aggramar on Heroic+ eh? Or, you wish hunters in PUGs did…
#showtooltip
/cast [nomod, @cursor] Freezing Trap
/cast [mod] Freezing Trap
Same as Freezing Trap, but this one makes everything sticky.
#showtooltip
/cast [nomod, @cursor] Tar Trap
/cast [mod] Tar Trap
Cancels Aspect of the Turtle if it’s up, otherwise, Turtle!
#showtooltip
/cancelaura Aspect of the Turtle
/use Aspect of the Turtle
If you haven’t bound the extra action button in the keybinds menu, you can use a macro for it like this:
/click ExtraActionButton1
Handy, you can buy specific items from vendors. For example, this allows you to buy the ingredients for Fish Brul Special that can be purchased with Blood of Sargeras from the vendor in Dalaran.
/script BuyMerchantItem(7)
/script BuyMerchantItem(8)
/script BuyMerchantItem(12)
This badass macro will mount up based on a few conditions. To explain:
/use [swimming][mod:alt,mod:ctrl]Azure Water Strider
/use [mod:alt]Grand Expedition Yak
/use [mod:ctrl]Sky Golem
/use [mod:shift]Arcanist's Manasaber
/use [noflyable]Steelbound Devourer
/run C_MountJournal.SummonByID(0)
/dismount [mounted]
I can never remember the command to show whether a quest ID is completed. Get the questid from wowhead or other wow database.
/script print(IsQuestFlaggedCompleted(33468))
Replace MAINTANK and OFFTANK with the main and off tank for your raid group to switch which one is your focus. This is useful for using assist, or casting Misdirection on the focus target.
/clearfocus
/focus [nomod] MAINTANK
/focus [mod] OFFTANK
I bind this to Control-C to cancel any attack and pet attack. Good for
Raid Lead: “STOP DPS!”
/stopcasting
/stopattack
/petfollow
/petpassive
Pop all on-use rings and trinkets, no matter which slot they’re in. This may not work in BfA with GCD changes.
#showtooltip
/use 11
/use 12
/use 13
/use 14